Subversion Repositories Projects

Rev

Rev 801 | Go to most recent revision | Blame | Compare with Previous | Last modification | View Log | RSS feed

# -------------------------------------------------
# Project created by QtCreator 2009-07-20T20:04:00
# -------------------------------------------------
include(../Global/Widget_Connection.pri)

# For Mac OS X, please define $QWT_HOME in your environment as path to QWT

QT += network
TARGET = QMK-Scope
TEMPLATE = app

TRANSLATIONS = $${TARGET}_en.ts \
               $${TARGET}_de.ts

win32 {
    include( C:\Qt\qwt-5.2.0\examples\examples.pri )
    QWT_ROOT = c:\qt\qwt-5.2.0
    include( $${QWT_ROOT}\qwtconfig.pri )
    SUFFIX_STR = $${RELEASE_SUFFIX}
    INCLUDEPATH += $${QWT_ROOT}/src
    DEPENDPATH += $${QWT_ROOT}/src
    QWTLIB = qwt$${SUFFIX_STR}
    contains(CONFIG, QwtDll)
     { 
        DEFINES += QT_DLL \
            QWT_DLL
        QWTLIB = $${QWTLIB}$${VER_MAJ}
    }
    win32-msvc:LIBS += $${QWT_ROOT}/lib/$${QWTLIB}.lib
    win32-msvc.net:LIBS += $${QWT_ROOT}/lib/$${QWTLIB}.lib
    win32-msvc2005:LIBS += $${QWT_ROOT}/lib/$${QWTLIB}.lib
    win32-g++:LIBS += -L$${QWT_ROOT}/lib \
        -l$${QWTLIB}
}

DESTDIR = ../Binary
OBJECTS_DIR = ../Binary/.build/$${TARGET}
UI_DIR = ../Binary/.build/$${TARGET}
MOC_DIR = ../Binary/.build/$${TARGET}
RCC_DIR = ../Binary/.build/$${TARGET}


# Mac specific stuff
macx:{
#    LIBS    += /System/Library/Frameworks/CoreFoundation.framework/CoreFoundation
    ICON = ../Global/Images/Icons/$${TARGET}.icns
    QMAKE_POST_LINK = cp ../$${TARGET}/*.qm ../Binary/$${TARGET}.app/Contents/MacOS/.
}

# And other
!macx:{
    QMAKE_POST_LINK = cp ../$${TARGET}/*.qm ../Binary/.
}

Suse { 
    LIBS += -lqwt
    INCLUDEPATH += $(HOME)/include \
        /usr/include/qwt
}

Debian { 
    LIBS += -lqwt-qt4
    INCLUDEPATH += $(HOME)/include \
        /usr/include/qwt-qt4
}

Gentoo { 
    LIBS += -lqwt
    INCLUDEPATH += $(HOME)/include \
        /usr/include/qwt5
}

OSX { 
    LIBS += -L$(QWT_HOME)/lib -lqwt
    INCLUDEPATH += $(QWT_HOME)/include
}

#debug {
#    DEFINES += _BETA_
#   LIBS += -lqwt
#   INCLUDEPATH += $(HOME)/include \
#        /usr/include/qwt
#}

RESOURCES += $${TARGET}.qrc
SOURCES += main.cpp \
    Dialogs/dlg_Main.cpp \
    Classes/cSettings.cpp \
    Dialogs/wgt_Index.cpp
HEADERS += Defines.h \
    ../Global/Global.h \
    Dialogs/dlg_Main.h \
    Classes/cSettings.h \
    TypeDefs.h \
    Dialogs/wgt_Index.h
FORMS += Dialogs/dlg_Main.ui \
    Dialogs/wgt_Index.ui